dev-libs/libisoburn: Version bump.

Package-Manager: Portage-2.3.8, Repoman-2.3.3

dev-libs/libisoburn/Manifest

@@ -1 +1,2 @@
 DIST libisoburn-1.4.6.tar.gz 1528141 SHA256 69efe9490e9ed6dbb1d8cad387ccaf5dcc5bb39dd466eef208a6b77a48584def SHA512 329d3234e8ae31abcab8d8a61a6531ab7ccdd8340148f84a6c77a23bbe16b303bf1dc95cafc751bf13f83e855f158b59ddd9e93c3dd1fe6046c1b5ea27eefb69 WHIRLPOOL 2b325541fe72e32acbd19c261a82b2c1475046467e33f5e1dd47d4aa64ed73f1a9f5d69281acd5978d65c046ff4c70dd7a4b6f3ef713f971e646cc5d12b7eb20
+DIST libisoburn-1.4.8.tar.gz 1537097 SHA256 91cf50473f0f19400629515974bda441545aaae29862dcbbdb28d87b821ca5a5 SHA512 26dd6f6884d98d9d3f54bf18b529a688d28aa0ff54b7fe6fe7926c7765755a1c7f7b2d0ef02ca6ea2bdac9ddf6f928c01c89a3547aea1e9f0b47346b160d0d46 WHIRLPOOL 88f2337bac0401f75a89e0ccfa5b259a87a282e7ce3594d02fc03da8765e3e164a77cdce38d959cbc31ad05798a7d0ad8887b601be0bfaf640adf39dd1378021

dev-libs/libisoburn/libisoburn-1.4.8.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="Creation/expansion of ISO-9660 filesystems on CD/DVD media supported by libburn"
+HOMEPAGE="https://dev.lovelyhq.com/libburnia/web/wikis/home"
+SRC_URI="http://files.libburnia-project.org/releases/${P}.tar.gz"
+
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="acl cdio debug external-filters external-filters-setuid frontend-optional
+	launch-frontend launch-frontend-setuid libedit readline static-libs xattr zlib"
+
+REQUIRED_USE="frontend-optional? ( || ( launch-frontend launch-frontend-setuid ) )"
+
+RDEPEND=">=dev-libs/libburn-1.4.8
+	>=dev-libs/libisofs-1.4.8
+	readline? ( sys-libs/readline:0= )
+	!readline? ( libedit? ( dev-libs/libedit ) )
+	acl? ( virtual/acl )
+	xattr? ( sys-apps/attr )
+	zlib? ( sys-libs/zlib )
+	cdio? ( >=dev-libs/libcdio-0.83 )
+	launch-frontend? ( dev-lang/tcl:0 dev-lang/tk:0 )
+	launch-frontend-setuid? ( dev-lang/tcl:0 dev-lang/tk:0 )
+	frontend-optional? ( dev-tcltk/bwidget )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_configure() {
+	econf \
+	$(use_enable static-libs static) \
+	$(use_enable readline libreadline) \
+	$(usex readline --disable-libedit $(use_enable libedit)) \
+	$(use_enable acl libacl) \
+	$(use_enable xattr) \
+	$(use_enable zlib) \
+	--disable-libjte \
+	$(use_enable cdio libcdio) \
+	$(use_enable external-filters) \
+	$(use_enable external-filters-setuid) \
+	$(use_enable launch-frontend) \
+	$(use_enable launch-frontend-setuid) \
+	--disable-ldconfig-at-install \
+	--enable-pkg-check-modules \
+	$(use_enable debug)
+}
+
+src_install() {
+	default
+
+	dodoc CONTRIBUTORS doc/{comments,*.wiki,startup_file.txt}
+
+	docinto frontend
+	dodoc frontend/README-tcltk
+	docinto xorriso
+	dodoc xorriso/{changelog.txt,README_gnu_xorriso}
+
+	find "${D}" -name '*.la' -delete || die
+}