jogos

Jogo Maior - Menor

Tente adivinha um número entre 1 e 100.

escreva "
        |Jogo Maior - Menor
        |"

numero = aleatório(1, 100) 

imprima "Eu escolhi um número entre 1 e 100. Tente adivinhar: "
var palpite := leia_inteiro

enquanto palpite <> numero faça
  se palpite < numero então
    imprima "O número é maior do que {palpite}: "
  senão
    imprima "O número é menor do que {palpite}: "
  fim
  palpite := leia_inteiro
fim
escreva "Parabéns, você ganhou!"

Jogo Maior-Menor

Agora pense em um número para o computador adivinhar

escreva "Jogo Maior Menor"
escreva "Pense em um número entre 1 e 100."
var menor := 1
var maior := 100
escreva "O número é maior, menor ou igual a 50?"
var resposta := leia_texto
enquanto resposta  <> "igual" faça
  metade = (maior + menor) div 2
  se resposta == "maior" então
    menor := metade
  senãose resposta == "menor" então
    maior := metade
  senão
    escreva "Não entendi."
  fim
  escreva "O número é maior, menor ou igual a {(maior + menor) div 2}?"
  resposta := leia_texto
fim
escreva "Consegui!"

Jogo da Velha

# Jogo da Velha
escreva "===== Jogo da Velha ====="
jogo = Matriz.mutavel(3, 3, " ") 

var jogadas := 0
var vitória := falso
var jogador := "X"

escreva jogo.mapeie(_.junte("|")).junte("\n-+-+-\n")
enquanto jogadas < 9 e não vitória faça
  escreva "Jogador {jogador}, qual a sua jogada?"
  x, y = leia_inteiro
  se jogo[x][y] == " " então
    jogo[x][y] := jogador
    jogador := se jogador == "X" então "O" senão "X" fim
    jogadas := jogadas + 1
    escreva jogo.mapeie(_.junte("|")).junte("\n-+-+-\n")
  fim
  
  # Verificar se alguém venceu
  para i de 1 até 3 faça
    se (jogo[i][1] == jogo[i][2] e jogo[i][1] == jogo[i][3] e jogo[i][1] <> " ") ou    # linha[i]
       (jogo[1][i] == jogo[2][i] e jogo[1][i] == jogo[3][i] e jogo[1][i] <> " ") então # coluna[i]
      vitória := verdadeiro
    fim
  fim
  se jogo[2][2] <> " " e (
       (jogo[1][1] == jogo[2][2] e jogo[1][1] == jogo[3][3]) ou      # diagonal 1
       (jogo[3][1] == jogo[2][2] e jogo[3][1] == jogo[1][3])         # diagonal 2
     ) então  
    vitória := verdadeiro
  fim  
fim

escreva "Fim de Jogo"