-
Notifications
You must be signed in to change notification settings - Fork 1
/
bigsub.v
104 lines (93 loc) · 2.89 KB
/
bigsub.v
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
////////////////////////////////////////////////////////////////////////////////
//
// Filename: bigsub.v
//
// Project: VideoZip, a ZipCPU SoC supporting video functionality
//
// Purpose: To subtract two 64-bit numbers, while maintaining
// synchronization to whatever purpose these numbers had
// originally. For this reason, there is an i_sync input and an o_sync
// output. If i_sync is true with a particular set of data, o_sync will
// then be true when that data is placed on the output.
//
// If we needed to slow this down even more, I suppose we could register
// the inputs before we used them ...
//
// Creator: Dan Gisselquist, Ph.D.
// Gisselquist Technology, LLC
//
////////////////////////////////////////////////////////////////////////////////
//
// Copyright (C) 2016-2017, Gisselquist Technology, LLC
//
// This program is free software (firmware): you can redistribute it and/or
// modify it under the terms of the GNU General Public License as published
// by the Free Software Foundation, either version 3 of the License, or (at
// your option) any later version.
//
// This program is distributed in the hope that it will be useful, but WITHOUT
// ANY WARRANTY; without even the implied warranty of MERCHANTIBILITY or
// FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
// for more details.
//
// You should have received a copy of the GNU General Public License along
// with this program. (It's in the $(ROOT)/doc directory. Run make with no
// target there if the PDF file isn't present.) If not, see
// <http://www.gnu.org/licenses/> for a copy.
//
// License: GPL, v3, as defined and found on www.gnu.org,
// http://www.gnu.org/licenses/gpl.html
//
//
////////////////////////////////////////////////////////////////////////////////
//
//
`default_nettype none
//
module bigsub(i_clk, i_sync, i_a, i_b, o_r, o_sync);
parameter NCLOCKS = 1;
input wire i_clk, i_sync;
input wire [63:0] i_a, i_b;
output wire [63:0] o_r;
output wire o_sync;
generate
if (NCLOCKS == 0)
begin
assign o_sync= i_sync;
assign o_r = i_a - i_b;
end else if (NCLOCKS == 1)
begin
reg r_sync;
reg [63:0] r_out;
always @(posedge i_clk)
r_sync <= i_sync;
always @(posedge i_clk)
r_out <= i_a - i_b;
assign o_sync = r_sync;
assign o_r = r_out;
end else // if (NCLOCKS == 2)
begin
reg r_sync, r_pps;
reg [31:0] r_hi, r_low;
reg [63:0] f_r;
reg f_sync;
wire [63:0] i_b_n;
assign i_b_n = ~i_b;
initial r_sync = 1'b0;
always @(posedge i_clk)
r_sync <= i_sync;
always @(posedge i_clk)
{ r_pps, r_low } <= i_a[31:0] + i_b_n[31:0] + 1'b1;
always @(posedge i_clk)
r_hi <= i_a[63:32] + i_b_n[63:32];
initial f_sync = 1'b0;
always @(posedge i_clk)
f_sync <= r_sync;
always @(posedge i_clk)
f_r[31:0] <= r_low;
always @(posedge i_clk)
f_r[63:32] <= r_hi + { 31'h00, r_pps };
assign o_sync = f_sync;
assign o_r = f_r;
end endgenerate
endmodule