build.gradle

/*
 * Copyright 2000-2017 JetBrains s.r.o.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
buildscript {
    ext.kotlinVersion='1.2.31'
    repositories {
        mavenLocal()
        mavenCentral()
        maven { url 'https://repository.jetbrains.com/repo/'}
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:${kotlinVersion}"
    }
}

plugins {
    id 'org.jetbrains.intellij' version '0.4.5'
}

version = '0.6.14'
if (System.hasProperty('build.number')) {
    version = "$version.${System.getProperty('build.number')}"
}
repositories {
    mavenLocal()
    mavenCentral()
    jcenter()
    maven { url 'https://repository.jetbrains.com/repo/'}
}

apply plugin: 'org.jetbrains.intellij'
apply plugin: 'kotlin'
apply plugin: 'idea'

intellij {
    version '2018.1'
    pluginName 'intellij-hcl'
    sandboxDirectory="${project.projectDir}/idea-sandbox"
    updateSinceUntilBuild = false
    plugins = ["com.intellij.plugins.watcher:${getFileWatcherPluginVersion(version)}"]
}

test {
    systemProperty('idea.platform.prefix', 'Idea')
}

// To prevent weird classpath problems in idea
clean {
    delete "${intellij.sandboxDirectory}/plugins/${intellij.pluginName}"
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib:${kotlinVersion}"
    compile 'com.beust:klaxon:0.31'
    testCompile 'org.assertj:assertj-core:2.6.0'
}

sourceCompatibility = '1.8'
targetCompatibility = '1.8'

sourceSets {
    main {
        java {
            srcDirs 'src/java', 'gen'
        }
        kotlin {
            srcDir 'src/kotlin'
        }
        resources {
            srcDir 'res'
        }
    }
    test {
        java {
            srcDir 'test'
        }
        resources {
            srcDir 'test-data'
        }
    }
}
processResources {
    // Minify json resources
    doLast {
        fileTree(dir: outputs.files.asPath, include: "**/*.json").each {
            File file -> file.text = groovy.json.JsonOutput.toJson(new groovy.json.JsonSlurper().parse(file))
        }
    }
}

if (System.getenv('TEAMCITY_VERSION') != null) {
    test.ignoreFailures = true
} else {
//test.testLogging.showStandardStreams = true
}

idea {
    module {
        excludeDirs += file(intellij.sandboxDirectory)
    }
}

wrapper {
    gradleVersion = '5.2.1'
}

import org.gradle.util.GradleVersion;
String getFileWatcherPluginVersion(String ideaVersion) {
    def version = GradleVersion.version(ideaVersion)

    if (version >= GradleVersion.version("2018.1") || ideaVersion.startsWith("181.")) {
        return "181.4096.12"
    }
    if (version >= GradleVersion.version("2017.3") || ideaVersion.startsWith("173.")) {
        return "173.3188.31"
    }
    if (version >= GradleVersion.version("2017.2") || ideaVersion.startsWith("172.")) {
        return "172.1909.7"
    }
    if (version >= GradleVersion.version("2017.1") || ideaVersion.startsWith("171.")) {
        return "171.1834.8"
    }
    if (version >= GradleVersion.version("2016.3") || ideaVersion.startsWith("163.")) {
        return "163.666"
    }
    if (version >= GradleVersion.version("2016.2") || ideaVersion.startsWith("162.")) {
        return "162.80"
    }
    return "143.110"
}