forked from GoVanguard/legion
-
Notifications
You must be signed in to change notification settings - Fork 0
/
nmap.xsl
1071 lines (873 loc) · 31.2 KB
/
nmap.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
<?xml version="1.0"?>
<!-- =========================================================================
nmap.xsl stylesheet version 0.9c
last change: 2010-12-28
Benjamin Erb, http://www.benjamin-erb.de
==============================================================================
Copyright (c) 2004-2006 Benjamin Erb
All rights reserved.
Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions
are met:
1. Redistributions of source code must retain the above copyright
notice, this list of conditions and the following disclaimer.
2. Redistributions in binary form must reproduce the above copyright
notice, this list of conditions and the following disclaimer in the
documentation and/or other materials provided with the distribution.
3. The name of the author may not be used to endorse or promote products
derived from this software without specific prior written permission.
THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
(INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
========================================================================== -->
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
<xsl:output
method="html"
indent="yes"
encoding="UTF-8"
doctype-public="-//W3C//DTD HTML 4.01//EN"
doctype-system="http://www.w3.org/TR/html4/strict.dtd"
/>
<!-- global variables -->
<!-- ............................................................ -->
<xsl:variable name="nmap_xsl_version">0.9c</xsl:variable>
<!-- ............................................................ -->
<xsl:variable name="start"><xsl:value-of select="/nmaprun/@startstr" /></xsl:variable>
<xsl:variable name="end"><xsl:value-of select="/nmaprun/runstats/finished/@timestr" /> </xsl:variable>
<xsl:variable name="totaltime"><xsl:value-of select="/nmaprun/runstats/finished/@time -/nmaprun/@start" /></xsl:variable>
<xsl:key name="portstatus" match="@state" use="."/>
<!-- ............................................................ -->
<xsl:template match="/">
<xsl:apply-templates/>
</xsl:template>
<!-- root -->
<!-- ............................................................ -->
<xsl:template match="/nmaprun">
<html>
<head>
<xsl:comment>generated with nmap.xsl - version <xsl:value-of select="$nmap_xsl_version" /> by Benjamin Erb - http://www.benjamin-erb.de/nmap_xsl.php </xsl:comment>
<style type="text/css">
/* stylesheet print */
@media print
{
#menu {
display:none;
}
body {
font-family: Verdana, Helvetica, sans-serif;
}
h1 {
font-size: 13pt;
font-weight:bold;
margin:4pt 0pt 0pt 0pt;
padding:0;
}
h2 {
font-size: 12pt;
font-weight:bold;
margin:3pt 0pt 0pt 0pt;
padding:0;
}
h3, a:link, a:visited {
font-size: 9pt;
font-weight:bold;
margin:1pt 0pt 0pt 20pt;
padding:0;
text-decoration: none;
color: #000000;
}
p,ul {
font-size: 9pt;
margin:1pt 0pt 8pt 40pt;
padding:0;
text-align:left;
}
li {
font-size: 9pt;
margin:0;
padding:0;
text-align:left;
}
table {
margin:1pt 0pt 8pt 40pt;
border:0px;
width:90%
}
td {
border:0px;
border-top:1px solid black;
font-size: 9pt;
}
.head td {
border:0px;
font-weight:bold;
font-size: 9pt;
}
.noprint { display: none; }
}
/* stylesheet screen */
@media screen
{
body {
font-family: Verdana, Helvetica, sans-serif;
margin: 0px;
background-color: #FFFFFF;
color: #000000;
text-align: center;
}
#container {
text-align:left;
margin: 10px auto;
width: 90%;
}
h1 {
font-family: Verdana, Helvetica, sans-serif;
font-weight:bold;
font-size: 14pt;
color: #FFFFFF;
background-color:#2A0D45;
margin:10px 0px 0px 0px;
padding:5px 4px 5px 4px;
width: 100%;
border:1px solid black;
text-align: left;
}
h2 {
font-family: Verdana, Helvetica, sans-serif;
font-weight:bold;
font-size: 11pt;
color: #000000;
margin:30px 0px 0px 0px;
padding:4px;
width: 100%;
background-color:#F0F8FF;
text-align: left;
}
h2.green {
color: #000000;
background-color:#CCFFCC;
border-color:#006400;
}
h2.red {
color: #000000;
background-color:#FFCCCC;
border-color:#8B0000;
}
h3 {
font-family: Verdana, Helvetica, sans-serif;
font-weight:bold;
font-size: 10pt;
color:#000000;
background-color: #FFFFFF;
width: 75%;
text-align: left;
}
p {
font-family: Verdana, Helvetica, sans-serif;
font-size: 8pt;
color:#000000;
background-color: #FFFFFF;
width: 75%;
text-align: left;
}
p i {
font-family: Verdana, Helvetica, sans-serif;
font-size: 8pt;
color:#000000;
background-color: #CCCCCC;
}
ul {
font-family: Verdana, Helvetica, sans-serif;
font-size: 8pt;
color:#000000;
background-color: #FFFFFF;
width: 75%;
text-align: left;
}
a {
font-family: Verdana, Helvetica, sans-serif;
text-decoration: none;
font-size: 8pt;
color:#000000;
font-weight:bold;
background-color: #FFFFFF;
color: #000000;
}
li a {
font-family: Verdana, Helvetica, sans-serif;
text-decoration: none;
font-size: 10pt;
color:#000000;
font-weight:bold;
background-color: #FFFFFF;
color: #000000;
}
a:hover {
text-decoration: underline;
}
a.up {
color:#006400;
}
table {
width: 80%;
border:0px;
color: #000000;
background-color: #000000;
margin:10px;
}
tr {
vertical-align:top;
font-family: Verdana, Helvetica, sans-serif;
font-size: 8pt;
color:#000000;
background-color: #FFFFFF;
}
tr.head {
background-color: #E1E1E1;
color: #000000;
font-weight:bold;
}
tr.open {
background-color: #CCFFCC;
color: #000000;
}
tr.script {
background-color: #EFFFF7;
color: #000000;
}
tr.filtered {
background-color: #F2F2F2;
color: #000000;
}
tr.closed {
background-color: #F2F2F2;
color: #000000;
}
td {
padding:2px;
}
#menu li {
display : inline;
margin : 0;
/*margin-right : 10px;*/
padding : 0;
list-style-type : none;
}
#menubox {
position: fixed;
bottom: 0px;
right: 0px;
width: 120px;
}
<![CDATA[
/* This section handle's IE's refusal to honor the fixed CSS attribute */
* html div#menubox {
position: absolute;
top:expression(eval(
document.compatMode && document.compatMode=='CSS1Compat') ?
documentElement.scrollTop+(documentElement.clientHeight-this.clientHeight)
: document.body.scrollTop +(document.body.clientHeight-this.clientHeight));
}
/* This fixes the jerky effect when scrolling in IE*/
* html,* html body {
background: #fff url(nosuchfile) fixed;
}
]]>
.up {
color: #000000;
background-color:#CCFFCC;
}
.down {
color:#626262;
background-color: #F2F2F2;
}
.print_only { display: none; }
.hidden { display: none; }
.unhidden { display: block; }
}
</style>
<title>Nmap Scan Report - Scanned at <xsl:value-of select="$start" /></title>
<script type="text/javascript">
<![CDATA[
function toggle(divID) {
var item = document.getElementById(divID);
if (item) {
item.className=(item.className=='hidden')?'unhidden':'hidden';
}
}
function togglePorts(tableID,portState) {
var table = document.getElementById(tableID);
var tbody = table.getElementsByTagName("tbody")[0];
var rows = tbody.getElementsByTagName("tr");
for (var i=0; i < rows.length; i++) {
var value = rows[i].getElementsByTagName("td")[2].firstChild.nodeValue;
if (value == portState) {
rows[i].style.display = (rows[i].style.display == 'none')?'':'none';
}
}
}
function toggleAll(portState) {
var allTables = document.getElementsByTagName("table");
for (var c=0; c < allTables.length; c++) {
if (allTables[c].id != "") {
togglePorts(allTables[c].id, portState)
}
}
}
function init (){
toggleAll('closed');
toggleAll('filtered');
}
window.onload = init;
]]>
</script>
</head>
<body>
<a name="top" />
<div id="container">
<h1>Nmap Scan Report - Scanned at <xsl:value-of select="$start" /></h1>
<ul id="menu">
<li><a href="#scansummary">Scan Summary</a></li>
<xsl:if test="prescript/script/@id">
<li>
<xsl:text> | </xsl:text>
<a href="#prescript">Pre-Scan Script Output</a>
</li>
</xsl:if>
<xsl:for-each select="host">
<xsl:sort select="substring ( address/@addr, 1, string-length ( substring-before ( address/@addr, '.' ) ) )* (256*256*256) + substring ( substring-after ( address/@addr, '.' ), 1, string-length ( substring-before ( substring-after ( address/@addr, '.' ), '.' ) ) )* (256*256) + substring ( substring-after ( substring-after ( address/@addr, '.' ), '.' ), 1, string-length ( substring-before ( substring-after ( substring-after ( address/@addr, '.' ), '.' ), '.' ) ) ) * 256 + substring ( substring-after ( substring-after ( substring-after ( address/@addr, '.' ), '.' ), '.' ), 1 )" order="ascending" data-type="number"/>
<li>
<xsl:text> | </xsl:text>
<xsl:element name="a">
<xsl:attribute name="href">#host_<xsl:value-of select="translate(address/@addr, '.', '_') " /></xsl:attribute>
<xsl:attribute name="class">
<xsl:choose>
<xsl:when test="status/@state = 'up'">up</xsl:when>
<xsl:otherwise>down</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<xsl:variable name="var_address" select="address/@addr" />
<xsl:if test="count(hostnames/hostname) > 0">
<xsl:for-each select="hostnames">
<xsl:choose>
<xsl:when test="hostname/@type='user'">
<xsl:value-of select="hostname/@name"/>
(<xsl:value-of select="$var_address"/>)
</xsl:when>
<xsl:otherwise>
<xsl:for-each select="hostname/@name[hostname/@type='PTR']"/>
<xsl:value-of select="hostname/@name"/> (<xsl:value-of select="$var_address"/>)
</xsl:otherwise>
</xsl:choose>
</xsl:for-each>
</xsl:if>
<xsl:if test="count(hostnames/hostname) = 0">
<xsl:value-of select="address/@addr"/>
</xsl:if>
</xsl:element>
</li>
</xsl:for-each>
<xsl:if test="postscript/script/@id">
<li> <xsl:text> | </xsl:text> <a href="#postscript">Post-Scan Script Output</a> </li>
</xsl:if>
</ul>
<xsl:element name="a">
<xsl:attribute name="name">scansummary</xsl:attribute>
</xsl:element>
<hr class="print_only" />
<h2>Scan Summary</h2>
<p>
Nmap <xsl:value-of select="@version" /> was initiated at <xsl:value-of select="$start" /> with these arguments:<br/>
<i><xsl:value-of select="@args" /></i><br/>
</p>
<p>
Verbosity: <xsl:value-of select="verbose/@level" />; Debug level <xsl:value-of select="debugging/@level" />
</p>
<p>
<xsl:value-of select="/nmaprun/runstats/finished/@summary" />
</p>
<xsl:apply-templates select="prescript"/>
<xsl:apply-templates select="host">
<xsl:sort select="substring ( address/@addr, 1, string-length ( substring-before ( address/@addr, '.' ) ) )* (256*256*256) + substring ( substring-after ( address/@addr, '.' ), 1, string-length ( substring-before ( substring-after ( address/@addr, '.' ), '.' ) ) )* (256*256) + substring ( substring-after ( substring-after ( address/@addr, '.' ), '.' ), 1, string-length ( substring-before ( substring-after ( substring-after ( address/@addr, '.' ), '.' ), '.' ) ) ) * 256 + substring ( substring-after ( substring-after ( substring-after ( address/@addr, '.' ), '.' ), '.' ), 1 )" order="ascending" data-type="number"/>
</xsl:apply-templates>
<xsl:apply-templates select="postscript"/>
</div>
<div id="menubox" class="noprint">
<a href="#top"><small>Go to top</small></a> <br />
<a href="javascript:toggleAll('closed');"><small>Toggle Closed Ports</small></a><br />
<a href="javascript:toggleAll('filtered');"><small>Toggle Filtered Ports</small></a>
</div>
</body>
</html>
</xsl:template>
<!-- ............................................................ -->
<!-- host -->
<!-- ............................................................ -->
<xsl:template match="host">
<hr class="print_only" />
<xsl:variable name="var_address" select="address/@addr" />
<xsl:element name="a">
<xsl:attribute name="name">host_<xsl:value-of select="translate(address/@addr, '.', '_') " /></xsl:attribute>
</xsl:element>
<xsl:choose>
<xsl:when test="status/@state = 'up'">
<h2 class="up"><xsl:value-of select="address/@addr"/>
<xsl:if test="count(hostnames/hostname) > 0">
<xsl:for-each select="hostnames/hostname">
<xsl:sort select="@name" order="ascending" data-type="text"/>
<xsl:text> / </xsl:text><xsl:value-of select="@name"/>
</xsl:for-each>
</xsl:if>
<span class="print_only">(online)</span>
</h2>
</xsl:when>
<xsl:otherwise>
<h2 class="down"><xsl:value-of select="address/@addr"/>
<xsl:if test="count(hostnames/hostname) > 0">
<xsl:for-each select="hostnames/hostname">
<xsl:sort select="@name" order="ascending" data-type="text"/>
<xsl:text> / </xsl:text><xsl:value-of select="@name"/>
</xsl:for-each>
</xsl:if>
<xsl:element name="a">
<xsl:attribute name="href">javascript:toggle('hostblock_<xsl:value-of select="$var_address"/>');</xsl:attribute>
<xsl:attribute name="class">host_down</xsl:attribute>
<span class="noprint"><small> (click to expand)</small></span>
</xsl:element>
<span class="print_only">(offline)</span></h2>
</xsl:otherwise>
</xsl:choose>
<xsl:element name="div">
<xsl:attribute name="id">hostblock_<xsl:value-of select="$var_address"/></xsl:attribute>
<xsl:choose>
<xsl:when test="status/@state = 'up'">
<xsl:attribute name="class">unhidden</xsl:attribute>
</xsl:when>
<xsl:otherwise>
<xsl:attribute name="class">hidden</xsl:attribute>
</xsl:otherwise>
</xsl:choose>
<xsl:if test="count(address) > 0">
<h3>Address</h3>
<ul>
<xsl:for-each select="address">
<li><xsl:value-of select="@addr"/>
<xsl:if test="@vendor">
<xsl:text> - </xsl:text>
<xsl:value-of select="@vendor"/>
<xsl:text> </xsl:text>
</xsl:if>
(<xsl:value-of select="@addrtype"/>)
</li>
</xsl:for-each>
</ul>
</xsl:if>
<xsl:apply-templates/>
<br />
<xsl:element name="a">
<xsl:attribute name="href">javascript:toggle('metrics_<xsl:value-of select="$var_address"/>');</xsl:attribute>
Misc Metrics <span class="noprint"><small> (click to expand)</small></span>
</xsl:element>
<xsl:element name="div">
<xsl:attribute name="id">metrics_<xsl:value-of select="$var_address"/></xsl:attribute>
<xsl:attribute name="class">hidden</xsl:attribute>
<table cellspacing="1">
<tr class="head">
<td>Metric</td>
<td>Value</td>
</tr>
<tr>
<td>Ping Results</td>
<td><xsl:value-of select="status/@reason"/>
<xsl:if test="status/@reasonsrc">
<xsl:text> from </xsl:text>
<xsl:value-of select="status/@reasonsrc"/>
</xsl:if>
</td>
</tr>
<xsl:if test="uptime/@seconds != ''">
<tr>
<td>System Uptime</td>
<td><xsl:value-of select="uptime/@seconds" /> seconds (last reboot: <xsl:value-of select="uptime/@lastboot" />)
</td>
</tr>
</xsl:if>
<xsl:if test="distance/@value != ''">
<tr>
<td>Network Distance</td>
<td><xsl:value-of select="distance/@value" /> hops</td>
</tr>
</xsl:if>
<xsl:if test="tcpsequence/@index != ''">
<tr>
<td>TCP Sequence Prediction</td>
<td>Difficulty=<xsl:value-of select="tcpsequence/@index" /> (<xsl:value-of select="tcpsequence/@difficulty" />)</td>
</tr>
</xsl:if>
<xsl:if test="ipidsequence/@class != ''">
<tr>
<td>IP ID Sequence Generation</td>
<td><xsl:value-of select="ipidsequence/@class" /></td>
</tr>
</xsl:if>
</table>
</xsl:element>
</xsl:element>
</xsl:template>
<!-- ............................................................ -->
<!-- hostnames -->
<!-- ............................................................ -->
<xsl:template match="hostnames">
<xsl:if test="hostname/@name != ''"><h3>Hostnames</h3><ul> <xsl:apply-templates/></ul></xsl:if>
</xsl:template>
<!-- ............................................................ -->
<!-- hostname -->
<!-- ............................................................ -->
<xsl:template match="hostname">
<li><xsl:value-of select="@name"/> (<xsl:value-of select="@type"/>)</li>
</xsl:template>
<!-- ............................................................ -->
<!-- ports -->
<!-- ............................................................ -->
<xsl:template match="ports">
<xsl:variable name="var_address" select="../address/@addr" />
<h3>Ports</h3>
<xsl:for-each select="extraports">
<xsl:if test="@count > 0">
<p>The <xsl:value-of select="@count" /> ports scanned but not shown below are in state: <b><xsl:value-of select="@state" /></b></p>
</xsl:if>
<ul>
<xsl:for-each select="extrareasons">
<xsl:if test="@count > 0">
<li><p><xsl:value-of select="@count" /> ports replied with: <b><xsl:value-of select="@reason" /></b></p></li>
</xsl:if>
</xsl:for-each>
</ul>
</xsl:for-each>
<xsl:if test="count(port) > 0">
<xsl:for-each select="port/state/@state[generate-id()=generate-id(key('portstatus',.))]" />
<xsl:variable name="closed_count" select="count(port/state[@state='closed'])" />
<xsl:variable name="filtered_count" select="count(port/state[@state='filtered'])" />
<xsl:element name="table">
<xsl:attribute name="id">porttable_<xsl:value-of select="$var_address"/></xsl:attribute>
<xsl:attribute name="cellspacing">1</xsl:attribute>
<tr class="head">
<td colspan="2">Port</td>
<td>State
<xsl:element name="a">
<xsl:attribute name="href">javascript:togglePorts('porttable_<xsl:value-of select="$var_address"/>','closed');</xsl:attribute>
<span class="noprint"><small> (toggle closed [<xsl:value-of select="$closed_count"/>] </small></span>
</xsl:element>
<xsl:element name="a">
<xsl:attribute name="href">javascript:togglePorts('porttable_<xsl:value-of select="$var_address"/>','filtered');</xsl:attribute>
<span class="noprint"><small> | filtered [<xsl:value-of select="$filtered_count"/>])</small></span>
</xsl:element>
</td>
<td>Service</td>
<td>Reason</td>
<td>Product</td>
<td>Version</td>
<td>Extra info</td>
</tr>
<xsl:apply-templates/>
</xsl:element>
</xsl:if>
</xsl:template>
<!-- ............................................................ -->
<!-- port -->
<!-- ............................................................ -->
<xsl:template match="port">
<xsl:choose>
<xsl:when test="state/@state = 'open'">
<tr class="open">
<td><xsl:value-of select="@portid" /></td>
<td><xsl:value-of select="@protocol" /></td>
<td><xsl:value-of select="state/@state" /></td>
<td><xsl:value-of select="service/@name" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="state/@reason"/>
<xsl:if test="state/@reason_ip">
<xsl:text> from </xsl:text>
<xsl:value-of select="state/@reason_ip"/>
</xsl:if>
</td>
<td><xsl:value-of select="service/@product" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="service/@version" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="service/@extrainfo" /><xsl:text> </xsl:text></td>
</tr>
<xsl:for-each select="script">
<tr class="script">
<td></td>
<td><xsl:value-of select="@id"/> <xsl:text> </xsl:text></td>
<td colspan="6">
<pre><xsl:value-of select="@output"/> <xsl:text> </xsl:text></pre>
</td>
</tr>
</xsl:for-each>
</xsl:when>
<xsl:when test="state/@state = 'filtered'">
<tr class="filtered">
<td><xsl:value-of select="@portid" /></td>
<td><xsl:value-of select="@protocol" /></td>
<td><xsl:value-of select="state/@state" /></td>
<td><xsl:value-of select="service/@name" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="state/@reason"/>
<xsl:if test="state/@reason_ip">
<xsl:text> from </xsl:text>
<xsl:value-of select="state/@reason_ip"/>
</xsl:if>
</td>
<td><xsl:value-of select="service/@product" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="service/@version" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="service/@extrainfo" /><xsl:text> </xsl:text></td>
</tr>
</xsl:when>
<xsl:when test="state/@state = 'closed'">
<tr class="closed">
<td><xsl:value-of select="@portid" /></td>
<td><xsl:value-of select="@protocol" /></td>
<td><xsl:value-of select="state/@state" /></td>
<td><xsl:value-of select="service/@name" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="state/@reason"/>
<xsl:if test="state/@reason_ip">
<xsl:text> from </xsl:text>
<xsl:value-of select="state/@reason_ip"/>
</xsl:if>
</td>
<td><xsl:value-of select="service/@product" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="service/@version" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="service/@extrainfo" /><xsl:text> </xsl:text></td>
</tr>
</xsl:when>
<xsl:otherwise>
<tr>
<td><xsl:value-of select="@portid" /></td>
<td><xsl:value-of select="@protocol" /></td>
<td><xsl:value-of select="state/@state" /></td>
<td><xsl:value-of select="service/@name" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="state/@reason"/>
<xsl:if test="state/@reason_ip">
<xsl:text> from </xsl:text>
<xsl:value-of select="state/@reason_ip"/>
</xsl:if>
</td>
<td><xsl:value-of select="service/@product" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="service/@version" /><xsl:text> </xsl:text></td>
<td><xsl:value-of select="service/@extrainfo" /><xsl:text> </xsl:text></td>
</tr>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!-- ............................................................ -->
<!-- os -->
<!-- ............................................................ -->
<xsl:template match="os">
<h3>Remote Operating System Detection</h3>
<xsl:if test="count(osmatch) = 0"><p>Unable to identify operating system.</p></xsl:if>
<ul>
<xsl:for-each select="portused">
<li>Used port: <b><xsl:value-of select="@portid" />/<xsl:value-of select="@proto" /> </b> (<b><xsl:value-of select="@state" /></b>) </li>
</xsl:for-each>
<xsl:for-each select="osmatch">
<li>OS match: <b><xsl:value-of select="@name" /> </b> (<b><xsl:value-of select="@accuracy" />%</b>)</li>
</xsl:for-each>
</ul>
<xsl:apply-templates select="osfingerprint"/>
</xsl:template>
<!-- ............................................................ -->
<!-- osfingerprint -->
<!-- ............................................................ -->
<xsl:template match="osfingerprint">
<xsl:variable name="var_address" select="../../address/@addr" />
<xsl:choose>
<xsl:when test="count(../osmatch)=0">
<ul>
<li>Cannot determine exact operating system. Fingerprint provided below.</li>
<li>If you know what OS is running on it, see https://nmap.org/submit/</li>
</ul>
<table cellspacing="1">
<tr class="head">
<td>Operating System fingerprint</td>
</tr>
<tr>
<td><pre><xsl:value-of select="@fingerprint" /></pre></td>
</tr>
</table>
</xsl:when>
<xsl:otherwise>
<ul>
<li class="noprint">OS identified but the fingerprint was requested at scan time.
<xsl:element name="a">
<xsl:attribute name="href">javascript:toggle('osblock_<xsl:value-of select="$var_address"/>');</xsl:attribute>
<span class="noprint"><small> (click to expand)</small></span>
</xsl:element>
</li>
</ul>
<xsl:element name="div">
<xsl:attribute name="id">osblock_<xsl:value-of select="$var_address"/></xsl:attribute>
<xsl:attribute name="class">hidden</xsl:attribute>
<table class="noprint" cellspacing="1">
<tr class="head">
<td>Operating System fingerprint</td>
</tr>
<tr>
<td><pre><xsl:value-of select="@fingerprint" /></pre></td>
</tr>
</table>
</xsl:element>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<!-- ............................................................ -->
<!-- Pre-Scan script -->
<!-- ............................................................ -->
<xsl:template match="prescript">
<hr class="print_only" />
<xsl:element name="a">
<xsl:attribute name="name">prescript</xsl:attribute>
</xsl:element>
<h2>Pre-Scan Script Output</h2>
<table>
<tr class="head">
<td>Script Name</td>
<td>Output</td>
</tr>
<xsl:for-each select="script">
<tr class="script">
<td>
<xsl:value-of select="@id"/> <xsl:text> </xsl:text>
</td>
<td>
<pre>
<xsl:value-of select="@output"/> <xsl:text></xsl:text>
</pre>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:template>
<!-- ............................................................ -->
<!-- Post-Scan script -->
<!-- ............................................................ -->
<xsl:template match="postscript">
<hr class="print_only" />
<xsl:element name="a">
<xsl:attribute name="name">postscript</xsl:attribute>
</xsl:element>
<h2>Post-Scan Script Putput</h2>
<table>
<tr class="head">
<td>Script Name</td>
<td>Output</td>
</tr>
<xsl:for-each select="script">
<tr class="script">
<td>
<xsl:value-of select="@id"/> <xsl:text> </xsl:text>
</td>
<td>
<pre>
<xsl:value-of select="@output"/> <xsl:text></xsl:text>
</pre>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:template>
<!-- ............................................................ -->
<!-- Host Script Scan -->
<!-- ............................................................ -->
<xsl:template match="hostscript">
<h3>Host Script Output</h3>
<table>
<tr class="head">
<td>Script Name</td>
<td>Output</td>
</tr>
<xsl:for-each select="script">
<tr class="script">
<td>
<xsl:value-of select="@id"/> <xsl:text> </xsl:text>
</td>
<td>
<pre>
<xsl:value-of select="@output"/> <xsl:text> </xsl:text>
</pre>
</td>
</tr>
</xsl:for-each>
</table>
</xsl:template>
<!-- ............................................................ -->
<!-- smurf -->
<!-- ............................................................ -->
<xsl:template match="smurf">
<xsl:if test="@responses != ''"><h3>Smurf Responses</h3>
<ul>
<li><xsl:value-of select="@responses" /> responses counted</li>
</ul>
</xsl:if>